Internet Info 1994 March/Internet Info CD-ROM (Walnut Creek) (March 1994).iso/networking/terms/kermit/a/msiwp3.com

Text File | 1993-08-07 | 4.1 KB | 117 lines

$! Procedure name :     PCWP.COM (version 2.0)
$! Date :        1APR90 (original)
$!            18JUL93 (update for MS-Kermit 3.13)
$!
$! Changes:    - Added support for the APC-MACRO
$!        - Removed TerminalR & TerminalS code (obsolete for usage
$!          in the 'old' manner, use the above. More Flexible!!)
$!        - Fixed minor Bug - Prompt NOW reappears upon
$!          leaving WordPerfect.
$!        - Added /nolog switch (a while back) to inhibit the
$!          annoying informational messages from VMS.
$!        - Now sets Graphics_size to VGA dimensions if not
$!          specified. See VGA NOTE below for info.
$!
$! Author :        Bob Martin
$! Address :        513 Ellis Ct.
$!            Richmond, KY 40475
$! Bitnet:        GRAPHICS@EKU  or   ACSMARTIN@EKU
$! Internet:        [e-mail] or [e-mail]
$!
$!#######################################################################
$!
$! This file is intended to provide a means for people to use
$! WordPerfect 5.x on a VAX(VMS), just as if they were using it on their
$! IBM PC. When used with the file 'WP30.INI' provided by WordPerfect
$! Corp. (I believe the file is called MSIWP3.INI at Columbia); you
$! will need to make minor corrections to the original INI file if
$! you are using VMS, since it was written for UNIX. As a matter of
$! fact, the MSIWP3.INI file is very well commented and tells you the
$! same thing.
$!
$! You can either use this command procedure locally (in your account)
$! or it can be made available to the entire system. I have made it
$! available to the entire system by putting it in a directory called
$! PUBLIC: -- then adding the line '$ PCWP :== @PUBLIC:PCWP.COM' to
$! SYLOGIN.COM.
$!
$! You may want to add 'SET KEY CLEAR' at the top of your MSKERMIT.INI
$! file to ensure you get ALL your VMS key definitions back.
$!
$! In the previous incarnation of this procedure, you had to define
$! TerminalS & TerminalR in your MSKERMIT.INI & WP30.INI files,
$! respectively. This method can no longer be used with MS-Kermit 3.13
$! since TerminalR & S are now used to support Hebrew (see MSKERM.UPD
$! for further details).
$!
$! VGA NOTE:
$!    The OLD usage of this procedure was 'PCWP VGA File.name' which
$!    still works! The program now assumes VGA if P1 isn't CGA, EGA,
$!    or VGA -- then uses P1 as the filename (wp file.name) and sets
$!    the Graphics_size to VGA dimensions (used with View Document).
$!    The worst this can cause is the document NOT fitting on the
$!    screen when viewing the document!
$!
$!    New Usage: PCWP file.name
$!
$! Hope it helps some of you folks out, a bit!
$!#######################################################################
$!
$!Set up the terminal...........
$!
$ set term/inq/noeight/hostsync/ttsync
$ create/name_table/nolog wpcorp_terminal_table
$ esc=""
$ esc[0,8]=27
$!
$! Uses APC-MACRO in order to provide hands-off key redefinition
$! for WordPerfect products
$!
$ define/nolog/table=wpcorp_terminal_table begin_control -
    "''esc'_ Take wp30.ini ''esc'\"
$!
$! Uses APC-MACRO -- which will reset your key definitions to
$! whatever you had them before, automatically.
$!
$ define/nolog/table=wpcorp_terminal_table end_control -
    "''esc'_ Take mskermit.ini ''esc'\ "
$!
$! This stuff will ASSUME VGA adapter if P1 is left out or misspelled
$! and use the 2nd parameter as the filename (P2).
$! It ain't pretty but it does work.... 8-)
$!
$ If ("''P1'" .eqs. "cga") .or. ("''P1'" .eqs. "CGA") then goto cga
$ If ("''P1'" .eqs. "ega") .or. ("''P1'" .eqs. "EGA") then goto ega
$ If ("''P1'" .eqs. "vga") .or. ("''P1'" .eqs. "VGA") then goto vga
$!
$! Assume P1 is misspelled and set up for VGA using P2 as filename.
$! This allows compatibility with version 1.0
$!
$ if P2 .nes. "" then goto vga
$!
$! Allows the usage 'PCWP file.name' and assumes VGA.
$!
$ if P1 .nes. "" then P2 = P1
$ goto vga
$!
$ CGA:
$ define/nolog/table=wpcorp_terminal_table graphics_size 320,200
$ define/user_mode sys$input sys$command
$ wp51 'P2'
$ goto outtahere
$!
$ EGA:
$ define/nolog/table=wpcorp_terminal_table graphics_size 640,350
$ define/user_mode sys$input sys$command
$ wp51 'P2'
$ goto outtahere
$!
$ VGA:
$ define/nolog/table=wpcorp_terminal_table graphics_size 640,480
$ define/user_mode sys$input sys$command
$ wp51 'P2'
$ goto outtahere
$!
$ outtahere:
$ Exit